From: Garry Boswell GBoswell@pcyc.com
Subject: [NMusers] Constant and Proportional Error with Log transformed data with single data point per subject  
Date: Thu, May 20, 2004 6:53 pm 

NM Users,
 
I have a PK study in mice in which I have a single blood sample
per mouse, groups of 6 mice per time point.  I have both IP and
IV data from both single and multiple dose administration.  During
the model building process it appeared that an additive plus
proportional error structure provided a better "fit" than other error
structures. As noted by Ette et al (JPP 23(5), 1995) with only a single
sample per animal I could not separately estimate interanimal and
residual variability.  Therefore I fixed Omega =0.  Using the code
below (error code suggested by Leonid Gibiansky in an earlier List
Serve post), I was able to fit the non-log transformed data but the
model was not adequate based on the diagnostic plots, etc.
 
I was able to fit the log transformed data using Y=log(F)+Err(1) as
described in NONMEM Tip #9.  However  I wanted to try the additive
plus proportional error structure but with log transformed data. 
NONMEM Tips #9 and #10 nicely address the method of doing this with
log transformed data but with what I believe is for data with multiple
samples from each individual.  My question is, can the methods 
described in these tips be applied to my model with Omega =0 FIXED?
 
TIA for any assistance.
 
Garry
 
$PROB DRUG X PK STUDY
$INPUT ID DAY=DROP TIME AMT MDV EVID DV LNDV WT SEX CMT SS II
$DATA Dataset_04.csv IGNORE=#
$SUBROUTINES  ADVAN2 TRANS2
$PK
  TVCL  = THETA(1)
  TVV    = THETA(2) 
  TVKA = THETA(3)
  TVF2  = THETA(4)  
 
  CL =TVCL* EXP(ETA(1))  
  V   =TVV 
  KA=TVKA
  F2 =TVF2 
 
  K    = CL/V
  HALF = (0.693/K)
  S2   = V
 
$ERROR
IPRED=F
IRES=DV-IPRED
IWRES=(DV-IPRED)/SQRT(F*F*THETA(1)*THETA(1)+THETA(2)*THETA(2) )
Y=F*(1+THETA(5)*EPS(1))+THETA(6)*EPS(2)
 
$THETA (0, 15)
$THETA (0, 10)
$THETA (0, 0.8)
$THETA (0, 0.7)
$THETA (0, 0.5)
$THETA (0, 0.01)
 
$OMEGA 0 FIXED
 
$SIGMA 1  FIXED
$SIGMA  1 FIXED
 
$EST  MAXEVALS = 9900  NOABORT
           SIGDIGITS =3  PRINT =10  POSTHOC
           METHOD=CONDITIONAL
 
$COV PRINT=E
 
$TABLE  NOPRINT ONEHEADER
           ID SEX TIME CL V KA F2 HALF WT 
           FILE=Outfile_04.txt

_______________________________________________________

From: Leonid Gibiansky lgibiansky@emmes.com
Subject: RE:[NMusers] Constant and Proportional Error with Log transformed data with single data point per subject  
Date: Fri, May 21, 2004 9:35 am  

Garry,
IWRES is computed incorrectly in your code (if it was similar in my post 
then I just mistyped it). There should be the same THETAs as in the error 
definition, i.e.,
IWRES=(DV-IPRED)/SQRT(F*F*THETA(5)*THETA(5)+
                                               THETA(6)*THETA(6) )
You may use it with the log-transformed data as follows:
>$ERROR
>IPRED=F
   IF(IPRED.LT.0.1) IPRED=0.1 ; use something small here, like LOQ/2 in 
place of 0.1
   W = SQRT( (THETA(5)/IPRED)**2 +THETA(6) )
   Y= LOG(IPRED)+W*EPS(1)
>IRES=DV-LOG(IPRED)
>IWRES=IRES/W

$SIGMA
1 FIXED

This is based on the posting by  Mats Karlsson as of Mon, 29 Apr 2002 (99apr232002.html), I 
copied it below:

Mats Karlsson wrote on Mon, 29 Apr 2002:
Hi,

To get the same error structure for log-transformed data as the
additive+proportional on the normal scale, I use
Y=LOG(F)+SQRT(THETA(x)**2+THETA(y)**2/F**2)*EPS(1)
with
$SIGMA 1 FIX

THETA(x) and THETA(y) will have the same meaning as on the untransformed scale
with

Y=F+SQRT(THETA(y)**2+THETA(x)**2*F**2)*EPS(1)
with
$SIGMA 1 FIX

....
cut here
=====================================


_______________________________________________________