NONMEM Users Network Archive

Hosted by Cognigen

Re: [NMusers] EM methods giving different outcomes at each repeated run

From: Jeroen Elassaiss-Schaap (PD-value B.V.) <"Jeroen>
Date: Wed, 28 Sep 2016 09:55:48 +0200

Dear Edgar,

What you describe is high stochastic noise in the EM algorithms. The
sampling integration needs to be accurate enough in order for these
algorithms to work properly. The first parameter to tune is ISAMPLE of
SAEM, I would start with 10 if you have less than 20 subjects. Accuracy
increases with the square root of ISAMPLE, so it sounds you probably are
going to need to tune more. I would look into Sobol sampling
(RANMETHOD=2S2). Are the stopping criteria reached in SAEM? If not,
consider more iterations (NBURN,NITER). Else, you may fare better with
more stringent stopping criteria (CINTERVAL to 20,50 or 100). Once SAEM
stabilizes with consistent parameters you can than go on and tune IMP
accordingly.

You may find Bob Bauer's tutorial at PAGE
(http://www.page-meeting.org/pdf_assets/9805-Bauer_EM_Methods_tutorial.pdf)
helpful; certainly the last 5 pages or so contain practical advices.

As a completely alternative approach you may want to consider to use
FOCE as a first step and than use IMP sampling only to get a covariance
matrix. Especially if you consider the FOCE parameter estimates to be
appropriate.

Hope this helps,
Jeroen


http://pd-value.com
jeroen_at_pd-value.com
_at_PD_value
+31 6 23118438
-- More value out of your data!

Op 26-09-16 om 22:33 schreef Edgar_Schuck_at_eisai.com:
> Hi all,
>
> I am new to the EM methods, but thought I would give it a try since I
> had no success in generating confidence intervals with the other more
> traditional methods. I am modeling a rich data set for a compound that
> has shown to have a second peak between 12 - 24 hours postdose. I have
> been able to get good runs with ITS followed by SAEM and IMP. The
> problem I am having is that if I repeat a run, with exactly the same
> settings and initial estimates, I get different results each time. Not
> only the estimates change, but the OFV does too, sometimes up to 10
> points. I have tried multiple alternatives, but I continuously have
> the same issue. Parameter estimates are generally fine, diagnostic
> plots are fine, residual variability is low, but I cannot to move into
> covariate analysis without understanding why is this happening. I
> remember seeing this before the first time I tried the EM methods, so
> my guess is that I am doing something wrong. The model below is the
> last one I ran, I would appreciate your help.
>
> thanks in advance,
>
> Edgar
>
> $INPUT C NMID=ID DOSE AMT MDV EVID TIME DV LNDV=DROP CMT
> $DATA XXX.CSV IGNORE=C
> $SUBROUTINES ADVAN13 TOL=9
>
> $MODEL
> COMP=(1_DOS, DEFDOSE) ; DOSE, 1
> COMP=(2_DOS) ; DOSE, 2
> COMP=(3_CENT, DEFOBS) ; CENTRAL
> COMP=(4_PERI) ; PERIPHERAL
> COMP=(5_ABS_2) ; TRANSIT 1
> COMP=(6_ABS_3) ; TRANSIT 2
> COMP=(7_ABS_3) ; TRANSIT 3
>
> $PK
>
> MU_1=LOG(THETA(1))
> CL=EXP(MU_1+ETA(1))
>
> MU_2=LOG(THETA(2))
> V3=EXP(MU_2+ETA(2))
>
> MU_3=LOG(THETA(3))
> Q=EXP(MU_3+ETA(3))
>
> MU_4=LOG(THETA(4))
> V4=EXP(MU_4+ETA(4))
>
> MU_5=LOG(THETA(5))
> KTR=EXP(MU_5+ETA(5))
>
> MU_6=LOG(THETA(6))
> KA1=EXP(MU_6+ETA(6)) ; First order rate of absorption for first
> absorption path
>
> MU_7=LOG(THETA(7))
> KA2=EXP(MU_7+ETA(7)) ; First order rate of absorption for second
> absorption path
>
> MU_8=LOG(THETA(8))
> FR1=EXP(MU_8+ETA(8))
>
> FR2=1-FR1
>
> S3=V3/1000
>
> K23 = KA2
> K30 = CL/V3
> K34 = Q/V3
> K43 = Q/V4
>
> $DES
> DADT(1) = -KA1*A(1)*FR1
> DADT(2) = -KTR*A(2)*FR2
> DADT(3) = KA1*FR1*A(1)+K43*A(4)-K34*A(3)-K30*A(3)+KA2*A(7)
> DADT(4) = K34*A(3)-K43*A(4)
> DADT(5) = KTR*A(2)*FR2 - KTR*A(5)
> DADT(6) = KTR*A(5) - KTR*A(6)
> DADT(7) = KTR*A(6) - KA2*A(7)
>
> $ERROR
> IPRE=F
> Y=F*(1+ERR(1))
>
> $EST METHOD=ITS INTERACTION NITER=50 NOABORT
> $EST METHOD=SAEM INTERACTION NBURN=1000 ISAMPLE=2 NITER=3000 CTYPE=3
> PRINT=200 SEED=1556678 NOABORT
> $EST METHOD=IMP INTERACTION EONLY=1 ISAMPLE=1000 NITER=20 MAPITER=20
> PRINT=1 MSFO=XXX.MSF
>
> $COVARIANCE UNCONDITIONAL SIGL=8 TOL=10
>
> $THETA
> (0,13,) ;[CL]
> (0,20) ;[V3]
> (0,60,) ;[Q]
> (0,200,) ;[V4]
> (0,1,) ;[KTR]
> (0,1,) ;[KA1]
> (0,3,) ;[KA2]
> (0,0.2,1) ;[FR1]
>
> $OMEGA
> 0.3 ;[P] CL
> 0.3 ;[P] V3
> 0.3 ;[P] Q
> 0.3 ;[P] V4
> 0.3 ;[P] KTR
> 0.3 ;[P] KA1
> 0.3 ;[P] KA2
> 0.3 ;[P] FR1
>
> $SIGMA
> 0.1 ;[P] sigma(1,1)
>
> $TABLE ID TIME IPRE CWRES ONEHEADER NOPRINT FILE=XXX.tab
>
> Here is a sample of the dataset:
>
>
>
>
> [This e-mail message may contain privileged, confidential and/or
> proprietary information of Eisai. If you believe that it has been sent
> to you in error, please contact the sender immediately and delete the
> message including any attachments, without copying, using, or
> distributing any of the information contained therein. This e-mail
> message should not be interpreted to include a digital or electronic
> signature that can be used to authenticate an agreement, contract or
> other legal document, nor to reflect an intention to be bound to any
> legally-binding agreement or contract.]


Received on Wed Sep 28 2016 - 03:55:48 EDT

The NONMEM Users Network is maintained by ICON plc. Requests to subscribe to the network should be sent to: nmusers-request@iconplc.com. Once subscribed, you may contribute to the discussion by emailing: nmusers@globomaxnm.com.