NONMEM Users Network Archive

Hosted by Cognigen

Re: [NMusers] Time varying volume of distribution implementation

From: Nick Holford <n.holford_at_auckland.ac.nz>
Date: Sat, 23 Apr 2016 10:43:07 +0200

Thorsten,

Time varying V is no different from time varying CL (or any other
parameter). You should use the variable T in $DES, not TIME, in order to
have the time at the instant the DEQ solver evaluates $DES. T may occur
anywhere in the interval between the previous record TIME and the
current record TIME. TIME in $PK, $DES and $ERROR is the time at the end
of the $DES solution interval.

The other thing that you may wish to do is to assign the random effect
expression for V and CL in $PK so that you can estimate the random
variability after accounting for the fixed effect variability in WT. An
expression involving ETA() cannot be used in $DES so it has to be
assigned in $PK.

e.g.

$PK
POP_V=THETA(1)
POP_CL=THETA(2)
WT_ZERO=THETA(3)
WT_ALPHA=THETA(4)
PPV_V=EXP(ETA(1)) ; random effect for V (PPV_V=population parameter
variability for V)
PPV_CL=EXP(ETA(2)) ; random effect for CLT (PPV_CL=population parameter
variability for CL)

$DES
;Variable names e.g. DWT_T are used in $DES because the same variable
names cannot be assigned in both $DES and in $ERROR

DWT_T=WT_ZERO + WT_ALPHA*T ; fixed effect prediction of WT at T

; Biology requires V and CL must both be functions of WT
DGRP_V=POP_V*DWT_T/70
DV=DGRP_V*PPV_V ; "individual" V at T using random effect for V

DGRP_CL=POP_CL*(DWT_T/70)**(3/4)
DCL=DGRP_CL*PPV_CL ; "individual" CL at T using random effect for CL

DADT(1)= -DCL*A(1)/DV

$ERROR

WT_T=WT_ZERO + WT_ALPHA*TIME ; fixed effect prediction of WT at the TIME
of the current record

GRP_V=POP_V*WT_T/70
GRP_CL=POP_CL*(WT_T/70)**(3/4)

V=VT*PPV_V ; "individual" V at the TIME of the current record
CL=GRP_CL*PPV_CL ; "individual" CL at the TIME of the current record

C=A(1)/V

You may, of course, add random effects to WT_ZERO and/or WT_ALPHA as
well as having random effects on V and CL.

BTW You should consider using the term postmenstrual age rather than
gestational age. Gestational age is a single value defined at the time
of delivery according to the American Academy of Pediatrics (Engle et al
2004). Postmenstrual age is a continuous variable which may be used
during pregnancy and after birth to represent the biological age of the
fetus/child.

Best wishes,

Nick

Engle WA. Age terminology during the perinatal period. Pediatrics.
2004;114(5):1362-4.


On 22-Apr-16 23:34, Thorsten Lehr wrote:
>
> Dear NMusers,
>
> I'm modeling a compound where body weight has a known impact on the
> volume of distribution. This compound is investigated in pregnant
> women over a long period (from gestational age of 8 weeks until they
> give birth). Consequently, the body weight changes over time and I
> have a decent formula to describe the individual body weight change.
> The PK model has to be coded by ODEs. Does anyone has experience how
> to integrate a time varying volume of distribution if differential
> equations are used?
>
> Best regards
>
> Thorsten
>
> --
>
> Thorsten Lehr, PhD
> Junior Professor of Clinical Pharmacy
> Saarland University
> Campus C2 2
> 66123 Saarbrücken
> Germany
>
> Office: +49/681/302-70255
> Mobile: +49/151/22739489
> thorsten.lehr_at_mx.uni-saarland.de
> www.clinicalpharmacy.me

--
Nick Holford, Professor Clinical Pharmacology
Dept Pharmacology & Clinical Pharmacology, Bldg 503 Room 302A
University of Auckland,85 Park Rd,Private Bag 92019,Auckland,New Zealand
office:+64(9)923-6730 mobile:NZ+64(21)46 23 53 FR+33(6)62 32 46 72
email: n.holford_at_auckland.ac.nz
http://holford.fmhs.auckland.ac.nz/

"Declarative languages are a form of dementia -- they have no memory of events"

Holford SD, Allegaert K, Anderson BJ, Kukanich B, Sousa AB, Steinman A, Pypendop, B., Mehvar, R., Giorgi, M., Holford,N.H.G. Parent-metabolite pharmacokinetic models - tests of assumptions and predictions. Journal of Pharmacology & Clinical Toxicology. 2014;2(2):1023-34.
Holford N. Clinical pharmacology = disease progression + drug action. Br J Clin Pharmacol. 2015;79(1):18-27.

Received on Sat Apr 23 2016 - 04:43:07 EDT

The NONMEM Users Network is maintained by ICON plc. Requests to subscribe to the network should be sent to: nmusers-request_at_iconplc.com. Once subscribed, you may contribute to the discussion by emailing: nmusers_at_globomaxnm.com.