Re: [NMusers] Different results with ADVAN4 and ADVAN6

From: Jeroen Elassaiss-Schaap (PD-value B.V.) <"Jeroen>
Date: Mon, 12 Dec 2016 12:40:14 +0100

Dear Hanna,

You might have hit a situation where the solver routine (ADVAN6) does
not provide an adequate solution to your $DES system (even though a
better fit). My advice would be to decrease the error tolerance of the
solution by increasing the number that now says TOL=5 until (up to 12
or 15 even) you get the same result compared to ADVAN4. If that does not
work, you could switch to ADVAN13 and try the same (the system might be
partly stiff).

If you would like to diagnose in more detail, you could create a dataset
with very dense interpolation entries (EVID=2) e.g. every 6 minutes. Any
irregularities in the resulting curves could point to a solver problem.
This might not give the complete picture, and you might suspect your
large estimate of KA to have an impact in that case. Perhaps some
different iterations with a simplified or partially fixed omega
structure might help than. It seems rather heavily parameterized for
what I guess is a phase 1 dataset.

Hope this helps,

Jeroen

http://pd-value.com
jeroen_at_pd-value.com
_at_PD_value
+31 6 23118438
-- More value out of your data!

On 12-12-16 10:13, Silber Baumann, Hanna wrote:
> Dear nmusers,
> I have a data set which contains single and multiple ascending dose
> data. The model development was initially performed on the single dose
> data.
> I initially developed a model using ADVAN4 TRANS 2 (2 compartment
> linear model with oral administration) which I later reparameterized
> into ADVAN6. I expected to see some minor differences in parameter
> estimates, OFV etc due to the change in subroutine but was surprised
> to see large differences in both parameter estimates and OFV (+180
> points) but also a significant improvement in overall fit
> (graphically) while the data was the same. With the ADVAN4 the model
> fit was particularly poor to parts of the multiple dose data, with the
> ADVAN6 the overall fit to all data was much improved. I was using
> NONMEM7.3 for the analysis.
>
> I guess the ADVAN4 model gets stuck in a local minima, but using the
> final estimates from the ADVAN6 model does not help. I would be
> grateful for an explanation of the reasons why this happens.
>
> I have included the two models below.
> Kind regards,
> Hanna Silber
>
> $PROBLEM PK with ADVAN4
>
> $INPUT C ID TAD TIME AMT DV EVID CMT PTIM LDV DOSE BW BMI CLCR SEX AGE
> STUDY DAY BLQ
>
> $DATA nmpk05DEC16.csv IGNORE=_at_
>
> $SUBROUTINES ADVAN4 TRANS4
>
> $PK
> CL = THETA(1) * EXP(ETA(1))
> V2 = THETA(2) * EXP(ETA(2))
> KA = THETA(3) * EXP(ETA(3))
> ALAG1 = THETA(6) * EXP(ETA(4))
> Q = THETA(7) * EXP(ETA(5))
> V3 = THETA(8) * EXP(ETA(6))
>
> S2 = V2/1000
>
> $ERROR
> IPRED = F
> W = SQRT(THETA(4)**2*IPRED**2 + THETA(5)**2)
> Y = IPRED + W*EPS(1)
> IRES = DV-IPRED
> IWRES = IRES/W
>
> $THETA
> (0,12.7) ;1 CL
> (0,275) ;2 V2
> (0,3.06) ;3 KA
> (0, 0.12) ;4 Prop.RE (sd)
> (0, 0.0153) ;5 Add.RE (sd)
> (0,0.474) ;6 ALAG1
> (0,26.3) ;7 Q
> (0,133) ;8 V3
>
> $OMEGA BLOCK(2) 0.0747 ;1 IIV CL
> 0.0723 0.0942 ;2 IIV V2
> $OMEGA
> 1.76 ;3 IIV KA
> 0.00166 ;4 IIV ALAG
> 0.036 ;5 IIV Q
> 0.0407 ;6 IIV V3
>
> $SIGMA
> 1 FIX ;
>
> $EST METHOD=1 INTER MAXEVAL=9999 NOABORT SIG=3 PRINT=1 POSTHOC
> $COV
> ######################################################
>
> $PROBLEM PK with ADVAN6
>
> $INPUT C ID TAD TIME AMT DV EVID CMT PTIM LDV DOSE BW BMI CLCR SEX AGE
> STUDY DAY BLQ
>
> $DATA nmpk05DEC16.csv IGNORE=_at_
>
> $SUBROUTINES ADVAN6 TOL=5
>
> $MODEL
> COMP = (ABS) ;1
> COMP = (CENT) ;2
> COMP = (PER) ;3
>
> $PK
> CL = THETA(1) * EXP(ETA(1))
> V2 = THETA(2) * EXP(ETA(2))
> KA = THETA(3) * EXP(ETA(3))
> ALAG1 = THETA(6) * EXP(ETA(4))
> Q = THETA(7) * EXP(ETA(5))
> V3 = THETA(8) * EXP(ETA(6))
>
> K=CL/V2
> K23 = Q/V2
> K32 = Q/V3
>
> A_0(1) = 0
> A_0(2) = 0
> A_0(3) = 0
>
> $DES
> DADT(1) = -KA*A(1)
> DADT(2) = KA*A(1) - K*A(2) - K23*A(2) + K32*A(3)
> DADT(3) = K23*A(2) - K23*A(3)
>
> $ERROR
> CONC = A(2)*1000/V2
> IPRED = CONC
> IF(CONC.EQ.0) IPRED = 1
>
> W = SQRT(THETA(4)**2*IPRED**2 + THETA(5)**2)
> Y = IPRED + W*EPS(1)
> IRES = DV-IPRED
> IWRES = IRES/W
>
> $THETA
> (0,12.1) ;1 CL
> (0,275) ;2 V2
> (0,3.06) ;3 KA
> (0, 0.12) ;4 Prop.RE (sd)
> (0, 0.0153) ;5 Add.RE (sd)
> (0,0.474) ;6 ALAG1
> (0,26.3) ;7 Q
> (0,133) ;8 V3
>
> $OMEGA BLOCK(2) 0.0747 ;1 IIV CL
> 0.0723 0.0942 ;2 IIV V2
> $OMEGA
> 1.76 ;3 IIV KA
> 0.00166 ;4 IIV ALAG
> 0.036 ;5 IIV Q
> 0.0407 ;6 IIV V3
>
> $SIGMA
> 1 FIX ;
>
> $EST METHOD=1 INTER MAXEVAL=9999 NOABORT SIG=3 PRINT=1 POSTHOC
> $COV
>
> ###############################
> Data set example:
> C ID TAD TIME AMT DV EVID CMT PTIM LDV DOSE BW BMI CLCR
> SEX AGE STUDY DAY BLQ
> 0 11001 0 0 5 0 1 1 0 0 5 54.8 20.63 74.32657 0 44 1
> 1 0
> 0 11001 0.5 0.5 0 1.94 0 2 0.5 0.662688 5 54.8 20.63
> 74.32657 0 44 1 1 0
> 0 11001 1 1 0 14.6 0 2 1 2.681022 5 54.8 20.63 74.32657
> 0 44 1 1 0
> 0 11001 1.5 1.5 0 22.4 0 2 1.5 3.109061 5 54.8 20.63
> 74.32657 0 44 1 1 0
> 0 11001 2 2 0 18.1 0 2 2 2.895912 5 54.8 20.63 74.32657
> 0 44 1 1 0
> 0 11001 2.5 2.5 0 15.4 0 2 2.5 2.734368 5 54.8 20.63
> 74.32657 0 44 1 1 0
> 0 11001 3 3 0 16.3 0 2 3 2.791165 5 54.8 20.63 74.32657
> 0 44 1 1 0
> 0 11001 4 4 0 15.5 0 2 4 2.74084 5 54.8 20.63 74.32657 0
> 44 1 1 0
> 0 11001 6 6 0 11.9 0 2 6 2.476538 5 54.8 20.63 74.32657
> 0 44 1 1 0
> 0 11001 8 8 0 11.5 0 2 8 2.442347 5 54.8 20.63 74.32657
> 0 44 1 1 0
> 0 11001 12 12 0 7.71 0 2 12 2.042518 5 54.8 20.63
> 74.32657 0 44 1 1 0
> 0 11001 16.017 16.017 0 8.71 0 2 16 2.164472 5 54.8 20.63
> 74.32657 0 44 1 2 0
> 0 11001 24 24 0 5.55 0 2 24 1.713798 5 54.8 20.63
> 74.32657 0 44 1 2 0
> 0 11001 48 48 0 3.5 0 2 48 1.252763 5 54.8 20.63 74.32657
> 0 44 1 3 0
> 0 11001 72 72 0 1.86 0 2 72 0.620576 5 54.8 20.63
> 74.32657 0 44 1 4 0
> 0 11001 120.883 120.883 0 0.597 0 2 120 -0.51584 5 54.8
> 20.63 74.32657 0 44 1 6 0
> 0 11001 144.9 144.9 0 0.356 0 2 144 -1.03282 5 54.8 20.63
> 74.32657 0 44 1 7 0
> 0 11001 168.883 168.883 0 0.177 0 2 168 -1.73161 5 54.8
> 20.63 74.32657 0 44 1 8 0
>
>
>
>
> --
>


Received on Mon Dec 12 2016 - 06:40:14 EST

This archive was generated by hypermail 2.3.0 : Fri Sep 27 2019 - 16:52:52 EDT